How to concatenate enter in Excel

View Discussion

Improve Article

Save Article

Like Article

View Discussion

Improve Article

Save Article

Like Article

Use CONCATENATE, one of the text capabilities, to join at least two text strings into one string. Significant: In Excel, Excel Mobile, and Excel for the web, this capability has been supplanted with the CONCAT capability. Assume you have an overview of data in Excel, yet by and by you really want to connect the summary by separating by Alt + Enter, how could it be that you could manage it? Here I will share two solutions to deal with this issue.

1. Concatenate columns with Alt + Enter by formula.
2. Concatenate columns with Alt + Enter by Kutools for Excel.

Concatenate Columns With Alt + Enter By Formula

This strategy will direct you to connect the information in every segment with the Alt + Enter by a recipe in Excel. Kindly do as follows:

• Select a clear cell you will put the link result, type the recipe =A1 and CHAR(10) and A2 and CHAR(10) and A3, and drag the AutoFill Handle right to different cells as the need might arise.

Note: In the recipe =A1 and CHAR(10) and A2 and CHAR(10) and A3, A1, A2, and A3 are cells you will link.

• Keep the recipe cell chosen, and click Home > Wrap Text.

Presently you will see every section is connected with Alt + Enter. See screen capture,

• Select the columns you will concatenate, and click Kutools > Combine. 

• In the Combine Columns or Rows dialog box, please,

1. Check the Combine rows option in the To combine selected cells according to the following options section.
2. Check the New line option in the Specify a separator section.
3. Check one of the options you need in the Options section. In my case, I check the Delete contents of the combined cells option.
4. Click the Ok button.

Presently you will see information in every section connected with Alt + Enter. 

Home ➜ Excel Formulas ➜ How to Concatenate with a Line Break in Excel

In Excel, when we normally combine text from different cells using CONCATENATE. But sometimes while doing this we need to add a line break between the text which we want to combine.

As you know there are serval methods to concatenate text but when it comes to adding a line break we need to use a specific formula for this.

Here’s the deal: To insert a line break between text we need to use the CHAR function.

And in today’s post, I’m going to show you exactly 3 different formulas which you can use to have a line break while combining values from different cells. And the best part is all these 3 formulas are simple to use.

In all these formulas there is one thing which is commonly we have used. That’s the CHAR function. This function returns a specific character according to the number you have specified in it.

And to enter a line break we need to mention 10 if you are using the Excel Windows version and 13 if you are using the Excel MAC version. You can learn more about CHAR from here, and now, let’s move on to our line break formulas.

1. Using an Ampersand with CHAR

This is actually a simple formula in which you need to refer to all the cells which you want to combine but by using CHAR(10) between those cell references. Look at this formula below:

=A2&CHAR(10)&B2&CHAR(10)&C2

Important Note: Once you enter this formula in a cell make sure to apply “Wrap Text” to that cell.

here’s how this formula works…

Actually, in this formula, we have combined a total of five values by using an ampersand (&). Three cell values and two CHAR function for line breaks. First, we have A2 and then a line break, after that B2 and again a line break and in the end, C2.

Related Tutorial: Remove Extra Spaces in Excel

2. Using CHAR with CONCATENATE Function

This formula is almost the same as we have used above but here instead of using an ampersand (&) we have simply used CONCATENATE function. Edit the cell and enter the below formula in it.

=CONCATENATE(A2,CHAR(10),B2,CHAR(10),C2)

Again in this formula, make sure to apply “Wrap Text” to the cell.

here’s how this formula works…

In this formula, we have combined 5 different things using CONCATENATE. Value from cell A2, line break using CHAR, Values from cell B2, line break, and in the end, value from cell C2.

3. Combination of CHAR and TEXTJOIN to Get a Line Break within Text

TEXTJOIN is the advanced version of CONCATENATE. In the function, you can use a delimiter to combine text from cells. And here is the formula to get a line break while concatenating text from different cells.

=TEXTJOIN(CHAR(10),TRUE,A2:C2)

In the formula, we used CHAR as a delimiter and then used TRUE to ignore empty cells. And in the end, selected the entire range A2:C2 which we need to combine. Now what happens is, as we have specified CHAR(10), it will add a line break after every cell value.

Conclusion

While using a line break in a formula the two things you need to take care of using the CHAR function for the line break and applying “Word Wrap” to the cell. From all the above formulas which we have learned here, I believe using TEXTJOIN is the simple and the best way.

I hope you found this formula tip useful, but you need to tell me one thing now.

Which formula do you think is the best to use? Share your views with me in the comment section, I’d love to hear from you, and make sure to share this tip which your friends as well.

🔙 Excel Formulas

In this article, you will learn various ways to concatenate text strings, cells, ranges, columns and rows in Excel using the CONCATENATE function and "&" operator.

In your Excel workbooks, the data is not always structured according to your needs. Often you may want to split the content of one cell into individual cells or do the opposite - combine data from two or more columns into a single column. Common examples are joining names and address parts, combining text with a formula-driven value, displaying dates and times in the desired format, to name a few.

In this tutorial, we are going to explore various techniques of Excel string concatenation, so you can choose the method best suited for your worksheets.

What is "concatenate" in Excel?

In essence, there are two ways to combine data in Excel spreadsheets:

• Merging cells
• Concatenating cells' values

When you merge cells, you "physically" join two or more cells into a single cell. As a result, you have one larger cell that is displayed across multiple rows and/or columns.

When you concatenate cells in Excel, you combine only the contents of those cells. In other words, concatenation in Excel is the process of joining two or more values together. This method is often used to combine a few pieces of text that reside in different cells (technically, these are called text strings or simply strings) or insert a formula-calculated value in the middle of some text.

The following screenshot demonstrates the difference between these two methods:

Merging cells in Excel is the subject of a separate article, and in this tutorial, we'll discuss the two main ways to concatenate strings in Excel - by using the CONCATENATE function and the concatenation operator (&).

Excel CONCATENATE function

The CONCATENATE function in Excel is used to join different pieces of text together or combine values from several cells into one cell.

The syntax of Excel CONCATENATE is as follows:

CONCATENATE(text1, [text2], …)

Where text is a text string, cell reference or formula-driven value.

The CONCATENATE function is supported in all versions of Excel for Microsoft 365, Excel 2019 - Excel 2007.

For example, to concatenate the values of B6 and C6 with a comma, the formula is:

=CONCATENATE(B6, ",", C6)

More examples are shown in the image below:

Note. In Excel 365 - Excel 2019, the CONCAT function is also available, which is a modern successor of CONCATENATE with exactly the same syntax. Although the CONCATENATE function is kept for backward compatibility, Microsoft does not give any promises that it will be supported in future versions of Excel.

Using CONCATENATE in Excel - things to remember

To ensure that your CONCATENATE formulas always deliver the correct results, remember the following simple rules:

• Excel CONCATENATE function requires at least one "text" argument to work.
• In one formula, you can concatenate up to 255 strings, a total of 8,192 characters.
• The result of the CONCATENATE function is always a text string, even when all of the source values are numbers.
• Unlike the CONCAT function, Excel CONCATENATE does not recognize arrays. Each cell reference must be listed separately. For example, you should use =CONCATENATE(A1, A2, A3) and not =CONCATENATE(A1:A3).
• If any of the arguments is invalid, the CONCATENATE function returns a #VALUE! error.

"&" operator to concatenate strings in Excel

In Microsoft Excel, the ampersand sign (&) is another way to concatenate cells. This method comes in very handy in many scenarios since typing an ampersand is much faster than typing the word "concatenate" :)

How to concatenate in Excel - formula examples

Below you will find a few examples of using the CONCATENATE function in Excel.

Concatenate two or more cells without separator

To combine the values of two cells into one, you use the concatenation formula in its simplest form:

=CONCATENATE(A2, B2)

Or

=A2&B2

Please note that the values will be knit together without any delimiter like in the screenshot below.

To concatenate multiple cells, you need to supply each cell reference individually, even if you are combining contiguous cells. For example:

=CONCATENATE(A2, B2, C2)

Or

=A2&B2&C2

The formulas work for both text and numbers. In case of numbers, please keep in mind that the result is a text string. To convert it to number, just multiply CONCATENATE's output by 1 or add 0 to it. For instance:

=CONCATENATE(A2, B2)*1

Tip. In Excel 2019 and higher, you can use the CONCAT function to quickly concatenate multiple cells using one or more range references.

Concatenate cells with a space, comma or other delimiter

In your worksheets, you may often need to join values in a way that includes commas, spaces, various punctuation marks or other characters such as a hyphen or slash. To do this, simply put the desired character in your concatenation formula. Remember to enclose that character in quotation marks, as demonstrated in the following examples.

Concatenating two cells with a space:

=CONCATENATE(A2, " ", B2)

or

=A2 & " " & B2

Concatenating two cells with a comma:

=CONCATENATE(A2, ", ", B2)

or

=A2 & ", " & B2

Concatenating two cells with a hyphen:

=CONCATENATE(A2, "-", B2)

or

=A2 & "-" & B2

The following screenshot demonstrates how the results may look like:

Tip. In Excel 2019 and higher, you can use the TEXTJOIN function to merge strings from multiple cells with any delimiter that you specify.

Concatenating text string and cell value

There is no reason for the Excel CONCATENATE function to be limited to only joining cells' values. You can also use it to combine text strings to make the result more meaningful. For example:

=CONCATENATE(A2, " ", B2, " completed")

The above formula informs the user that a certain project is completed, as in row 2 in the screenshot below. Please notice that we add a space before the word " completed" to separate the concatenated text strings. A space (" ") is also inserted between the combined values, so that the result displays as "Project 1" rather than "Project1".

With the concatenation operator, the formula can be written this way:

=A2 & " " & B2 & " completed"

In the same manner, you can add a text string in the beginning or in the middle of your concatenation formula. For example:

=CONCATENATE("See ", A2, " ", B2)

="See " & A2 & " " & B2

Join text string and another formula

To make the result returned by some formula more understandable for your users, you can concatenate it with a text string that explains what the value actually is.

For example, you can use the following formula to return the current date in the desired format and specify what kind of date that is:

=CONCATENATE("Today is ",TEXT(TODAY(), "mmmm d, yyyy"))

="Today is " & TEXT(TODAY(), "dd-mmm-yy")

Tip. If you would like to delete the source data without affecting the resulting text strings, use the "Paste special - values only" option to convert formulas to their values.

Concatenate text strings with line breaks

Most often, you would separate the resulting text strings with punctuation marks and spaces, as shown in the previous example. In some cases, however, there may be a need to separate the values with a line break, or carriage return. A common example is merging mailing addresses from data in separate columns.

A problem is that you cannot simply type a line break in the formula like a usual character. Instead, you use the CHAR function to supply the corresponding ASCII code to the concatenation formula:

• On Windows, use CHAR(10) where 10 is the character code for Line feed.
• On Mac, use CHAR(13) where 13 is the character code for Carriage return.

In this example, we have the address pieces in columns A through F, and we are putting them together in column G by using the concatenation operator "&". The merged values are separated with a comma (", "), space (" ") and a line break CHAR(10):

=A2 & " " & B2 & CHAR(10) & C2 & CHAR(10) & D2 & ", " & E2 & " " & F2

The CONCATENATE function would take this shape:

=CONCATENATE(A2, " ", B2, CHAR(10), C2, CHAR(10), D2, ", ", E2, " ", F2)

Either way, the result is a 3-line text string:

Note. When using line breaks to separate the combined values, you must have Wrap text enabled for the result to display correctly. To do this, press Ctrl + 1 to open the Format Cells dialog, switch to the Alignment tab and check the Wrap text box.

In the same manner, you can separate final strings with other characters such as:

• Double quotes (") - CHAR(34)
• Forward slash (/) - CHAR(47)
• Asterisk (*) - CHAR (42)
• The full list of ASCII codes is available here.

How to concatenate columns in Excel

To join two or more columns, just enter your concatenation formula in the first cell, and then copy it down to other cells by dragging the fill handle (the small square that appears in the lower right hand corner of the selected cell).

For example, to combine two columns (column A and B) delimiting the values with a space, the formula in C2 copied down is:

=CONCATENATE(A2, " ", B2)

Or

= A2 & " " & B2

Tip. A quick way to copy the formula down the column is to select the cell with the formula and double-click the fill handle.

For more information, please see How to merge two columns in Excel without losing data.

Combine text and numbers keeping formatting

When concatenating a text string with a number, percentage or date, you may want to keep the original formatting of a numeric value or display it in a different way. This can be done by supplying the format code inside the TEXT function, which you embed in a concatenation formula.

In the beginning of this tutorial, we have already discussed a formula that concatenates text and date.

And here are a few more formula examples that combine text and number:

Number with 2 decimal places and the $ sign:

=A2 & " " & TEXT(B2, "$#,#0.00")

Number without insignificant zeros and the $ sign:

=A2 & " " & TEXT(B2, "0.#")

Fractional number:

=A2 & " " & TEXT(B2, "# ?/???")

To concatenate text and percentage, the formulas are:

Percent with two decimal places:

=A12 & " " & TEXT(B12, "0.00%")

Rounded whole percent:

=A12 & " " & TEXT(B12, "0%")

How to concatenate a range of cells in Excel

Combining values from multiple cells might take some effort because the Excel CONCATENATE function does not accept arrays.

To concatenate several cells, say A1 to A4, you need to use one of the following formulas:

=CONCATENATE(A1, A2, A3, A4)

or

=A1 & A2 & A3 & A4

When combining a fairly small group of cells, it's no big deal to type all the references. A large range would be tedious to supply, typing each individual reference manually. Below you will find 3 methods of quick range concatenation in Excel.

Method 1. Press CTRL to select multiple cells

To quickly select several cells, you can press and hold the Ctrl key while clicking on each cell you want to include in the formula. Here are the detailed steps:

1. Select a cell where you want to enter the formula.
2. Type =CONCATENATE( in that cell or in the formula bar.
3. Press and hold Ctrl and click on each cell you want to concatenate.
4. Release the Ctrl button, type the closing parenthesis, and press Enter.

Note. When using this method, you must click each individual cell. Selecting a range with the mouse would add an array to the formula, which the CONCATENATE function does not accept.

Method 2. Use TRANSPOSE function to get all cell values

When a range consists of tens or hundreds of cells, the previous method may not be fast enough as it requires clicking on each cell. In this case, you can use the TRANSPOSE function to return an array of values, and then merge them together in one fell swoop.

1. In the cell where you want the result to appear, enter the TRANSPOSE formula, for example:=TRANSPOSE(A1:A10)
2. In the formula bar, press F9 to replace the formula with calculated values. As a result, you will have an array of values to be concatenated.
3. Delete the curly braces surrounding the array.
   
4. Type =CONCATENATE( before the first value, then type the closing parenthesis after the last value, and press Enter.
   

Note. The result of this formula is static as it concatenates the values, not cell references. If the source data changes, you will have to repeat the process.

Method 3. Use the CONCAT function

In Excel 365 and Excel 2021, this simple formula will concatenate a range of cells in a blink:

=CONCAT(A1:A10)

Method 4. Use the Merge Cells add-in

A quick and formula-free way to concatenate any range in Excel is to use the Merge Cells add-in with the "Merge all areas in selection" option turned off, as demonstrated in Combining values of several cells into one cell.

Excel "&" operator vs. CONCATENATE function

Many users wonder which is a more efficient way to join strings in Excel - CONCATENATE function or "&" operator.

The only real difference is the 255 strings limit of the CONCATENATE function and no such limitation when using the ampersand. Other than that, there is no difference between these two methods, nor is there any speed difference between the CONCATENATE and "&" formulas.

And since 255 is a really big number and you will hardly ever need to combine that many strings in real work, the difference boils down to comfort and ease of use. Some users find CONCATENATE formulas easier to read, I personally prefer using the "&" method. So, simply stick with the technique you feel more comfortable with.

Opposite of CONCATENATE in Excel (splitting cells)

The opposite of concatenate in Excel is splitting the contents of one cell into multiple cells. This can be done in a few different ways:

You can also find useful information in this article: How to unmerge cells in Excel.

Concatenate in Excel with Merge Cells add-in

With the Merge Cells add-in included in Ultimate Suite for Excel, you can efficiently do both:

• Merge several cells into one without losing data.
• Concatenate the values of several cells into a single cell and separate them with any delimiter of your choosing.

The Merge Cells tool works with all Excel versions from 2016 to 365 and can combine all data types including text strings, numbers, dates and special symbols. Its two key advantages are simplicity and speed - any concatenation is done in a couple of clicks.

Combine values of several cells into one cell

To combine the contents of several cells, you select the range to concatenate and configure the following settings:

• Under What to merge, select Cells into one.
• Under Combine with, type the delimiter (a comma and a space in our case).
• Choose where you want to place the result.
• Most importantly, uncheck the Merge all areas in the selection box. It is this option that controls whether the cells are merged or their values are concatenated.

Combine columns row-by-row

To concatenate two or more columns, you configure the Merge Cells' settings in a similar way but choose to merge columns into one and place the results in the left column.

Join rows column-by-column

To combine data in each individual row, column-by-column, you choose:

• Merge rows into one.
• Use a line break for the delimiter.
• Place the results in the top row.

The result may look similar to this:

To check how the Merge Cells add-in will cope with your data sets, you are welcome to download a fully functional trial version of our Ultimate Suite for Excel below.

That's how to concatenate in Excel. I thank you for reading and hope to see you on our blog next week!

Available downloads

Concatenation formula examples (.xlsx file)
Ultimate Suite 14-day trial version (.zip file)